!% -SD

! This work is licensed under the Creative Commons Attribution-Noncommercial 3.0 Singapore License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc/3.0/sg/ or send a letter to Creative Commons, 171 Second Street, Suite 300, San Francisco, California, 94105, USA.

!===============================================================================
Constant Story "Bus station";
Constant Headline
            "^A simple story fragment
             ^by Alex Mitchell.^";
Constant MAX_CARRIED 1;

Include "Parser";
Include "VerbLib";

!===============================================================================
! The game objects

Object  waiting_room "Waiting room"
  with  description
            "You are standing in a dingy, rundown waiting room in a bus terminal. The main entrance is to the north. To the south are the bus stands. To the west you can see a row of lockers.  East leads is the men's toilet. In the middle of the room is a single, cold, bare metal bench.",
        e_to toilet,
	s_to "The bus isn't here yet. Better wait in the waiting room until it arrives.",
	w_to lockers,
	n_to "It's pouring down with rain outside. You'd better stay here."
  has   light;

Object  bench "bench" waiting_room
  with  description "A cold metal bench, at least its somewhere to rest.",
        name 'cold' 'metal' 'seat' 'chair' 'bench',
  has   static scenery supporter enterable;

Object  newspaper "newspaper" bench
  with  description "A crumpled copy of today's paper. Looks like its been used to soak up some sticky liquid.",
        name 'paper' 'newspaper' 'news' 'scrap' 'rag',
        before [;
          Consult:
            print_ret "Nothing about your family. Perhaps tomorrow's paper will mention something? Surely someone must have found them by now...";
        ],
  has   ;

Object  stands "Bus stands"
  with  description
            "A row of bus stands.",
        n_to waiting_room,
        before [;
          Go:
            print_ret "The bus isn't here yet. Better wait in the waiting room until it arrives.";
        ],
  has   light;

Object  toilet "Men's toilet"
  with  description
            "The men's toilet smells like a men's toilet. A row of urinals occupies one wall. Along the opposite wall are several cubicles, all locked except one, which is missing its door.",
        w_to waiting_room,
  has   light;

Object cubicles "cubicles" toilet
	with description "The cubicles look, and smell, like they haven't been washed for years.",
		name 'cubicles' 'cubicle' 'stalls' 'stall',
has static scenery;

Object urinals "urinals" toilet
	with description "The urinals have seen better days.",
		name 'urinals' 'urinal',
has static scenery;

Object  lockers "Lockers"
  with  description
            "This small alcove contains a row of storage lockers.",
        e_to waiting_room,
  has   light;

! this locker can be opened with the key
Object locker "locker" lockers
  with description
	    "A standard locker.",
         name 'locker' 'lockers',
	 with_key key
  has static scenery container openable lockable locked;

! inside the locker...
Object diary "diary" locker
  with description
	"A small diary. The handwriting looks very familiar. You suddenly feel a wave of nausea, and look away.",
         before [;
            Take:
               print_ret "As you start to pick up the diary, you are overcome with a strong sense of foreboding. You quickly put the diary back in the locker.";
         ],
         name 'diary' 'book' 'journal',
   has ;

! inventory objects

! key to the locker
Object key "key"
  with description
	"A small key, looks like it might fit into a storage locker.",
	 name 'key',
has ;

!===============================================================================
! Entry point routines

[ Initialise; 
	location = bench; 
	move key to player;	
];

!===============================================================================
! Standard and extended grammar

Include "Grammar";

!===============================================================================